Nickin sunucudaki durumu

Bu kodun çalişma mantıgı istediginiz bir nicki herhangi bir sunucuda kontrol etmek için işe yarıyor. Nick sunucudamı değil mi onun hakkında bilgi veriyor. Whois bilgilerine bakmanızı sagLiyor. Status?den bilgileri takip edebilirsiniz.

Socks bot olarak baglaniyor sunucuya. Bagli olan socks botu görmek için /socklist yazın. Bagli olan socks botu sunucudan cıkarmak için /sockclose inuser yazınız.

alias inuser {
$iif($hget(nick),hfree nick) | unset %net | var %e = echo $color(info text) -ste * /inuser: Hatalı veya eksik kullanım:
if (!$1 || !$2) { %e /inuser <nick> <network> | return }
if ($regex($1,(?<=^\d)) && $regex($1,(\w{1,30}))) { %e IRC sunucularında herhangi bir nick <rakam> ile başlayamaz. | return }
if (!$regex($2,(\w{3,})(\.{1})(\w{2,}))) { %e Sunucu adresini %80 oranında yanlış girdiniz. | return }
var %irc = $+(irc.,$2) | set %net %irc | hadd -m nick $1 1
if (%irc != $sock(inuser).addr) { $iif($sock(inuser),sockclose inuser) | sockopen inuser %irc 6667 } | else sockwrite -n inuser ison $1
echo $color(info text) -st * /inuser: $qt($1) rumuzu $qt(%irc) sunucusunda aranıyor.
}
on *:sockopen:inuser: {
var %s = sockwrite -n $sockname,%n = $+($hget(nick,1).item,$r(0,99)),%id = $+(Kontrol,$r(1,9999))
if ($sockerr) { echo $color(info text) -ste Sunucuya bağlanılamadı. Kontrol ederek tekrar deneyiniz. | return }
%s NICK %n | %s USER mIRCalem * * $+(:,%id) | sockmark $sockname %n
}
on *:sockread:inuser: {
if ($sockerr) { echo $color(info text) -ste Sunucuya bağlanılamadı. Kontrol ederek tekrar deneyiniz. | return }
sockread %: | tokenize 32 %: | var %n: = $regsubex($token($1,1,33),:,)
if ($regex($2,^PRIVMSG$) && $regex($3,$sock($sockname).mark) && $regex($4-,VERSION))  {
sockwrite -n $sockname notice %n: : VERSION mIRC $version Khaled Mardam-Bey
}
if ($regex($1,^PING$)) { sockwrite -n $sockname pong $2- }
if ($regex($2,^JOIN$) && %n: == $sock($sockname).mark) { sockwrite -n $sockname part $regsubex($3,:,) }
if ($regex($2,^001$)) { sockwrite -n $sockname ison $hget(nick,1).item }
if ($regex($2,^303$) && $3 == $sock($sockname).mark) {
if ($regsubex($4,:,) == $hget(nick,1).item) { echo $color(info text) -ste * /inuser: Aradığınız $qt($hget(nick,1).item) rumuzu, $qt(%net) sunucusunda online. Bilgilerini görüntülemek için; $qt(tıklayın.) }
else echo $color(info text) -ste * /inuser: Aradığınız $qt($hget(nick,1).item) rumuzu, $qt(%net) sunucusunda bulunmuyor.
}
if ($3 == $sock($sockname).mark && $4 == $hget(nick,1).item) {
if ($regex($2,^401$)) { echo $color(info text) -st * /inuser: $qt($4) bilgileri alınamadı. (Nick değiştirmiş veya çıkmış olabilir) }
if ($regex($2,^311$)) { echo -st Adresi: $+($chr(2),$4,!,$5,@,$6) | echo -st Gerçek isim: $+($chr(2),$right($8-,-1)) }
if ($regex($2,^307$)) { echo -st Kayıt bilgisi: $+($chr(2),Kayıtlı ve kullanılamaz nick.) }
if ($regex($2,^319$)) { echo -st Bulunduğu kanallar: $+($chr(2),$right($5-,-1)) }
if ($regex($2,^313$)) { echo -st INFO: $+($chr(2),$7-) }
if ($regex($2,^317$)) { echo -st Konuşmadığı süre: $+($chr(2),$duration($5)) | echo -st Bağlantı zamanı: $+($chr(2),$asctime($6,dd/mm/yy – hh:nn:ss)) }
if ($regex($2,^318$)) { echo -ste $+($chr(2),$hget(nick,1).item,$chr(2)) rumuzunun bilgi sonu. }
}
}
on ^*:hotlink:*”tıklayın.”*:status window:if ($1 == $qt(tıklayın.)) return
on *:hotlink:*”tıklayın.”*:status window:if ($sock(inuser).status) { echo -ste $+($chr(2),$hget(nick,1).item,$chr(2)) rumuzunun bilgileri sıralanıyor. | sockwrite -n inuser whois $hget(nick,1).item }

alıntıdır.